home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d1 / freemacs.arc / DEV11.ASM < prev    next >
Assembly Source File  |  1988-03-17  |  7KB  |  248 lines
  1.         name    DEV
  2.         page    60,132
  3.         title   'DEV --- Report installed device drivers'
  4.  
  5. ; DEV --- a utility to report device header information for
  6. ;         all installed device drivers
  7. ; 
  8. ; Requires PC-DOS or MS-DOS 2.0.
  9. ;
  10. ; Used in the form:
  11. ; A>DEV 
  12. ;
  13. ; version 1.0   December 12, 1984
  14. ; Copyright (c) 1984 by Ray Duncan
  15. ;
  16. ; version 1.1   October 19, 1986
  17. ; modified by Brian J. Larson
  18. ;
  19. ; In DOS 3.2 the reserved area of the FCB has been changed.  The
  20. ; segment still seems right but the offset does not point to NUL
  21. ; so 48h is forced into the offset. Reserved must mean RESERVED!
  22. ;
  23. cr      equ     0dh             ;ASCII carriage return
  24. lf      equ     0ah             ;ASCII line feed
  25. blank    equ    20h        ;ASCII space code
  26. eom    equ    '$'        ;end of string marker
  27.  
  28.  
  29. cseg    segment    para public 'CODE'
  30.  
  31.     assume    cs:cseg,ds:data,es:data,ss:stack
  32.  
  33.  
  34. dev     proc    far             ;entry point from PC-DOS
  35.  
  36.         push    ds              ;save DS:0000 for final
  37.         xor     ax,ax           ;return to PC-DOS
  38.         push    ax
  39.         mov     ax,data         ;make our data segment
  40.     mov    ds,ax        ;addressable via DS and ES.
  41.     mov     es,ax 
  42.         mov     ah,30h        ;check version of PC-DOS.    
  43.         int     21h
  44.         cmp     al,2
  45.         jae     dev1        ;proceed, DOS 2.0 or greater.
  46.         mov     dx,offset msg2  ;DOS 1.x --- print error message.
  47.     jmp    dev6
  48.  
  49. dev1:    mov    cx,ax        ;save DOS version number.
  50.     mov    ah,15        ;now try and open the "NUL" device.
  51.     mov    dx,offset nulfcb
  52.     int    21h
  53.     or    al,al        ;opened successfully?
  54.     jz    dev2        ;yes, jump.
  55.     mov    dx,offset msg1    ;no, print error msg and exit.
  56.     jmp    dev6
  57.  
  58. dev2:                ;Pick up double pointer to device 
  59.                 ;driver chain out of reserved
  60.                 ;area in fcb.  This area is mapped
  61.                 ;differently in DOS 2.x and DOS 3.x.
  62.     cmp    cl,2        ;is this DOS 2.x?
  63.     ja    dev3        ;no, jump.
  64.     mov    bx,word ptr nulfcb+25
  65.     mov    es,word ptr nulfcb+27
  66.     jmp    dev4
  67.  
  68. dev3:                ;come here if DOS 3.0 or greater.
  69.     cmp    ch,2        ;compare minor - DOS 3.2 or greater?
  70.     jae    dev32        ;yes, jump.
  71.     mov    bx,word ptr nulfcb+26
  72.     mov    es,word ptr nulfcb+28
  73.     jmp    dev4
  74.  
  75. dev32:                ;come here if DOS 3.2 or above
  76.     mov    bx,48h        ;value at nulfcb+26 is C2h but NUL is at 48h
  77.     mov    es,word ptr nulfcb+28
  78.  
  79. dev4:    call    header        ;print sign-on message and 
  80.                 ;column headings.
  81.  
  82. dev5:                ;trace through the device chain
  83.  
  84.     call    prdev        ;print device header information
  85.                 ;for driver pointed to by ES:BX.
  86.                 ;pick up addr of next header.
  87.     les    bx,dword ptr es:[bx]
  88.     cmp    bx,-1        ;found last one yet?
  89.     jne    dev5        ;no, try next.
  90.     
  91.           mov    dx,offset msg3    ;yes, print "end of device chain".
  92.  
  93. dev6:     mov    ah,9        ;print the string whose address
  94.     int    21h        ;is in DX.
  95.     ret            ;then return to DOS.
  96.  
  97. dev       endp
  98.  
  99.  
  100. header    proc    near        ;print out headings for device
  101.     mov    dx,offset hdr    ;driver information.
  102.     mov    ah,9
  103.     int    21h
  104.     ret
  105. header    endp
  106.  
  107.  
  108. prdev    proc    near        ;print out device driver info.
  109.                 ;ES:BX is pointer to device header,
  110.                 ;which must be preserved.
  111.     mov    ax,es        ;convert segment of device header
  112.     mov    di,offset inf1
  113.     call    hexasc
  114.     mov    ax,bx        ;convert offset of device header.
  115.     mov    di,offset inf2
  116.     call    hexasc
  117.     mov    ax,es:[bx+4]    ;get attribute word, save a 
  118.     push    ax        ;copy of it, then convert it.
  119.     mov    di,offset inf3
  120.     call    hexasc
  121.     mov    ax,es:[bx+6]    ;convert ptr to device strategy.
  122.     mov    di,offset inf4
  123.     call    hexasc
  124.     mov    ax,es:[bx+8]    ;convert ptr to device int handler.
  125.     mov    di,offset inf5
  126.     call    hexasc
  127.  
  128.                 ;if not char device, clear out name
  129.                 ;field and set number of units.
  130.     pop    ax        ;get back attribute word.
  131.     test    ax,08000h    ;is bit 15 = 1 ?
  132.     jnz    prdev7        ;yes, it's character dev, jump.
  133.                           ;no, it's block device.
  134.                 ;set flag to skip device name.
  135.     mov     byte ptr inf8,eom
  136.     mov    al,es:[bx+10]    ;pick up number of units.
  137.     aam            ;convert to ASCII decimal and
  138.     add    ax,'00'        ;store into output string.
  139.     mov    byte ptr inf7+1,al
  140.     mov    byte ptr inf7,ah
  141.                 ;set type = B for Block
  142.     mov    byte ptr inf6,'B'    
  143.     jmp    prdev9
  144.  
  145. prdev7:                ;if char device, move its 8-character
  146.                 ;name into the output string.
  147.     xor    si,si
  148. prdev8:    mov    al,es:[si+bx+10]
  149.     mov    [si+inf8],al
  150.     inc    si
  151.     cmp    si,8
  152.     jne    prdev8
  153.                 ;remove # of units field.
  154.     mov    word ptr inf7,'  '
  155.                 ;set type = C for Character.
  156.     mov    byte ptr inf6,'C'
  157.  
  158. prdev9: mov    dx,offset inf    ;now print device information
  159.     mov    ah,9        ;and exit.
  160.     int    21h
  161.     ret
  162. prdev    endp
  163.  
  164. hexasc    proc    near        ;convert binary word to hex ASCII.
  165.                 ;call with AX=binary value
  166.                 ;          DI=addr to store string 
  167.                 ;returns AX, CX, DI destroyed.
  168.     push    ax        ;save copy of original value.
  169.     mov    al,ah
  170.     call    btoa        ;convert upper byte.
  171.     add    di,2        ;increment output address.
  172.     pop    ax
  173.     call    btoa        ;convert lower byte.
  174.     ret            ;return to caller.
  175. hexasc    endp
  176.  
  177. btoa    proc    near        ;convert binary byte to hex ASCII.
  178.                 ;call with AL=binary value 
  179.                 ;          DI=addr to store string
  180.                 ;returns AX, CX destroyed.
  181.     mov    ah,al        ;save lower nibble.
  182.     mov    cx,4        ;shift right 4 positions
  183.     shr    al,cl        ;to get upper nibble.
  184.     call    ascii        ;convert 4 bits to ASCII equivalent
  185.     mov    [di],al        ;store into output string.
  186.     mov    al,ah        ;get back lower nibble.
  187.     and    al,0fh
  188.     call    ascii        ;convert 4 bits to ASCII
  189.     mov     [di+1],al    ;and store into output string.
  190.     ret            ;back to caller.
  191. btoa    endp
  192.  
  193. ascii    proc    near        ;convert 4 lower bits of AL
  194.     add    al,'0'        ;into the equivalent ASCII char.
  195.     cmp    al,'9'        ;in the range {0...9,A...F}
  196.     jle    ascii2        ;and return char. in AL.
  197.     add    al,'A'-'9'-1    ;"fudge factor" for range A-F.
  198. ascii2:    ret            ;return to caller.
  199. ascii    endp
  200.  
  201. cseg    ends
  202.  
  203.  
  204. data    segment para public 'DATA'
  205.  
  206. msg1    db    cr,lf
  207.     db    'Failed to open NUL device.'
  208.     db    cr,lf,eom
  209.  
  210. msg2    db      cr,lf
  211.         db      'Requires DOS version 2 or greater.'
  212.         db      cr,lf,eom
  213.  
  214. msg3    db    cr,lf
  215.     db    'End of device chain.'
  216.     db    cr,lf,eom
  217.  
  218. hdr    db    cr,lf
  219.     db    'Addr      Attr '
  220.     db    'Str  Int   Type  Units  Name   '
  221.     db    eom
  222.  
  223.  
  224. inf     db    cr,lf
  225. inf1    db    'XXXX:'        ;seg device header
  226. inf2    db    'XXXX '        ;offs device header
  227. inf3    db    'XXXX '        ;attribute
  228. inf4    db    'XXXX '        ;strategy
  229. inf5    db    'XXXX   '    ;interrupt handler
  230. inf6    db    'X     '    ;type (block or char)
  231. inf7    db    'XX    '    ;units (if block device)
  232. inf8    db    '         '    ;name  (if char device)
  233.     db    eom
  234.  
  235.                 ;fcb to open NUL device
  236. nulfcb    db    0        ;drive
  237.     db    'NUL'        ;name of NUL device
  238.     db    8 dup (' ')
  239.     db    25 dup (0)
  240. data    ends    
  241.  
  242.  
  243. stack   segment para stack 'STACK'
  244.         db      64 dup (?)
  245. stack   ends
  246.  
  247.         end     dev
  248.